MQL4 Reference MQL4命令手册(完整版)

IndicatorDigits
void IndicatorDigits( int digits)
设置精确格式(计数数字在小数点以后)使自定义值直观化。货币对精确价格 为默认值。 指标会添加到图表中。
参量:
digits   -   精确格式。
示例:
int init()
  {
//---- 使用及计算2个添加缓冲。
   IndicatorBuffers(3);
//---- 画出参量设置
   SetIndexStyle(0,DRAW_HISTOGRAM,STYLE_SOLID,3);
   SetIndexDrawBegin(0,SignalSMA);
   IndicatorDigits(Digits+2);
//----一个自定义的3个缓冲
   SetIndexBuffer(0,ind_buffer1);
   SetIndexBuffer(1,ind_buffer2);
   SetIndexBuffer(2,ind_buffer3);
//---- DataWindow 和自定义子窗口"简称"
   IndicatorShortName("OsMA("+FastEMA+","+SlowEMA+","+SignalSMA+")");
//---- 初始化完成
   return(0);
  }

IndicatorShortName
void IndicatorShortName( string name)
设置显示在数据窗口和子窗口中自定义指标的"简称"。
参量:
name   -   新简称。
示例:
int init()
  {
//----使用计算2个添加缓冲
   IndicatorBuffers(3);
//---- 画出设定
   SetIndexStyle(0,DRAW_HISTOGRAM,STYLE_SOLID,3);
   SetIndexDrawBegin(0,SignalSMA);
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS)+2);
//---- 绘制3个添加缓冲位置
   SetIndexBuffer(0,ind_buffer1);
   SetIndexBuffer(1,ind_buffer2);
   SetIndexBuffer(2,ind_buffer3);
//---- DataWindow 和自定义子窗口标签名称
   IndicatorShortName("OsMA("+FastEMA+","+SlowEMA+","+SignalSMA+")");
//---- 初始化完成
   return(0);
  }

SetIndexArrow
void SetIndexArrow( int index, int code)
设置DRAW_ARROW 类型的自定义线为一个箭头货币对。
箭头代码范围限于33到255之间。
参量:
index   -   索引线。必须在0至7之间。
code   -   来自Wingdings 或 数组常数的货币对代码。
示例:
int init()
  {
//---- 2 个自定义缓冲
    SetIndexBuffer(0,ExtUppperBuffer);
    SetIndexBuffer(1,ExtLowerBuffer);
//---- 绘制参量设置
    SetIndexStyle(0,DRAW_ARROW);
    SetIndexArrow(0,217);
    SetIndexStyle(1,DRAW_ARROW);
    SetIndexArrow(1,218);
//---- 在DataWindow窗口显示
    SetIndexLabel(0,"Fractal Up");
    SetIndexLabel(1,"Fractal Down");
//---- 初始化完成
   return(0);
  }

SetIndexBuffer
bool SetIndexBuffer( int index, double array[])
对于自定义指标预定义的缓冲器绑定全球水平。需要使用IndicatorBuffers() 函数计算缓冲器的总数并且不能超过8。如果成功，返回TRUE，否则将返回FALSE。获得详细信息，请查看 GetLastError()函数。
参量:
index   -   索引线。必须在0至7之间。
array[]   -   数组存储计算指标值。
示例:
  double ExtBufferSilver[];
  int init()
    {
      SetIndexBuffer(0, ExtBufferSilver); // 第一线缓冲
      // ...
    }

SetIndexDrawBegin
void SetIndexDrawBegin( int index, int begin)
从给出指标线画出必须开始设置柱数字(从数据开始) 。指标线会从左到右画出所给出指标数组值左边部分不会显示在图表或数据窗口中。设置0作为默认值, 随后，所有数据将得出。
参量:
index   -   索引线。必须在0至7之间。
begin   -   第一个画出柱的数字位置。
示例:
int init()
  {
//----使用计算2个添加缓冲
   IndicatorBuffers(3);
//----画出设定
   SetIndexStyle(0,DRAW_HISTOGRAM,STYLE_SOLID,3);
   SetIndexDrawBegin(0,SignalSMA);
   IndicatorDigits(MarketInfo(Symbol(),MODE_DIGITS)+2);
//---- 绘制3个添加缓冲位置
   SetIndexBuffer(0,ind_buffer1);
   SetIndexBuffer(1,ind_buffer2);
   SetIndexBuffer(2,ind_buffer3);
//---- DataWindow 和自定义子窗口标签名称
   IndicatorShortName("OsMA("+FastEMA+","+SlowEMA+","+SignalSMA+")");
//---- 初始化完成
   return(0);
  }

SetIndexEmptyValue
void SetIndexEmptyValue( int index, double value)
设置图画线省缺值。省缺值不得出或不被显示在DataWindow 。省缺值是EMPTY_VALUE。
参量:
index   -   索引线。必须在0至7之间。
value   -   新 "省缺值"。
示例:
int init()
  {
//----2个添加缓冲
    SetIndexBuffer(0,ExtUppperBuffer);
    SetIndexBuffer(1,ExtLowerBuffer);
//---- 画出参量设置
    SetIndexStyle(0,DRAW_ARROW);
    SetIndexArrow(0,217);

SetIndexStyle(1,DRAW_ARROW);
    SetIndexArrow(1,218);
//---- 值0 不显示
    SetIndexEmptyValue(0,0.0);
    SetIndexEmptyValue(1,0.0);
//---- 在DataWindow窗口不显示
    SetIndexLabel(0,"Fractal Up");
    SetIndexLabel(1,"Fractal Down");
//---- 初始化完成
   return(0);
  }

SetIndexLabel
void SetIndexLabel( int index, string text)
在DataWindow 和tooltip中设置图画线描述。
参量:
index   -   索引线。必须在0至7之间。
text   -   标签文本。 NULL 表示索引值在DataWindow不显示。
示例:
//+------------------------------------------------------------------+
//| Ichimoku Kinko Hyo initialization function                       |
//+------------------------------------------------------------------+
int init()
  {
//----
   SetIndexStyle(0,DRAW_LINE);
   SetIndexBuffer(0,Tenkan_Buffer);
   SetIndexDrawBegin(0,Tenkan-1);
   SetIndexLabel(0,"Tenkan Sen");
//----
   SetIndexStyle(1,DRAW_LINE);
   SetIndexBuffer(1,Kijun_Buffer);
   SetIndexDrawBegin(1,Kijun-1);
   SetIndexLabel(1,"Kijun Sen");
//----
   a_begin=Kijun; if(a_begin<Tenkan) a_begin=Tenkan;
   SetIndexStyle(2,DRAW_HISTOGRAM,STYLE_DOT);
   SetIndexBuffer(2,SpanA_Buffer);
   SetIndexDrawBegin(2,Kijun+a_begin-1);
   SetIndexShift(2,Kijun);
//---- 在DataWindow窗口Up Kumo线不显示
   SetIndexLabel(2,NULL);
   SetIndexStyle(5,DRAW_LINE,STYLE_DOT);
   SetIndexBuffer(5,SpanA2_Buffer);
   SetIndexDrawBegin(5,Kijun+a_begin-1);
   SetIndexShift(5,Kijun);
   SetIndexLabel(5,"Senkou Span A");
//----
   SetIndexStyle(3,DRAW_HISTOGRAM,STYLE_DOT);
   SetIndexBuffer(3,SpanB_Buffer);
   SetIndexDrawBegin(3,Kijun+Senkou-1);
   SetIndexShift(3,Kijun);
//---- 在DataWindow窗口Down Kumo 线不显示
   SetIndexLabel(3,NULL);
//----
   SetIndexStyle(6,DRAW_LINE,STYLE_DOT);
   SetIndexBuffer(6,SpanB2_Buffer);
   SetIndexDrawBegin(6,Kijun+Senkou-1);
   SetIndexShift(6,Kijun);
   SetIndexLabel(6,"Senkou Span B");
//----
   SetIndexStyle(4,DRAW_LINE);
   SetIndexBuffer(4,Chinkou_Buffer);
   SetIndexShift(4,-Kijun);
   SetIndexLabel(4,"Chinkou Span");
//----
   return(0);
  }

SetIndexShift
void SetIndexShift( int index, int shift)
撤销画线设置。对于仓位值，画线将会平移到右侧或是平移到左侧。在当前柱计算值将被平移到相应的柱。
参量:
index   -   索引线。必须在0至7之间。
shift   -   平移植。
示例:
//+------------------------------------------------------------------+
//| Alligator initialization function                                |
//+------------------------------------------------------------------+
int init()
  {
//----当画出时线平移
   SetIndexShift(0,JawsShift);
   SetIndexShift(1,TeethShift);
   SetIndexShift(2,LipsShift);
//---- 当画出时越过地一个位置
   SetIndexDrawBegin(0,JawsShift+JawsPeriod);
   SetIndexDrawBegin(1,TeethShift+TeethPeriod);
   SetIndexDrawBegin(2,LipsShift+LipsPeriod);
//---- 绘制3个添加缓冲位置
   SetIndexBuffer(0,ExtBlueBuffer);
   SetIndexBuffer(1,ExtRedBuffer);
   SetIndexBuffer(2,ExtLimeBuffer);
//---- 画出设定
   SetIndexStyle(0,DRAW_LINE);
   SetIndexStyle(1,DRAW_LINE);
   SetIndexStyle(2,DRAW_LINE);
//---- 索引标签
   SetIndexLabel(0,"Gator Jaws");
   SetIndexLabel(1,"Gator Teeth");
   SetIndexLabel(2,"Gator Lips");
//---- 初始化完成
   return(0);
  }

SetIndexStyle
void SetIndexStyle( int index, int type, void style, void width, void clr)
设置新型、样式、宽度和颜色为一条指定的显示线。
参量:
index   -   索引线。必须在0至7之间。
type   -   样式风格。可以是划线风格列表其中一个。
style   -   画线风格。可以应用单线。可以是划线风格列表其中一个。 EMPTY 值表示风格不变。
width   -   线的宽度。线的宽度可以是1,2,3,4,5。 EMPTY 值表示着风格不变。
clr   -   线的颜色。.现存的参量表示颜色将不会改变。
示例:
  SetIndexStyle(3, DRAW_LINE, EMPTY, 2, Red);