一款带有源码的均线EA

Moving Average_ch EA采用均线策略在交易。所以函数都用中文做了详细注释，对新手学习EA不愧为很好的例子。
QQ截图20170407091838.png

Moving Average_ch.mq4

2017-4-7 09:18

点击文件名下载附件

//+------------------------------------------------------------------+
//| Moving Average.mq4 |
//| Copyright @2005, MetaQuotes Software Corp. |
//+------------------------------------------------------------------+
#property copyright "下载更多外汇EA，外汇指标，交易系统，就到【外汇EA之家】"
#property link "http://www.eazhijia.com"
#define MAGICMA 20050610//#define是宏定义命令。这个定义了本EA操作的订单的唯一标识号码MAGICMA，由此可以实现在同一账户上多系统操作，各操作EA的订单标识码不同，就不会互相误操作。凡是EA皆不可缺少，非常非常重要！这个定义本EA操作的订单的唯一标识号码MAGICMA，由此可以实现在同一账户上多系统操作，各操作EA的订单标识码不同，就不会互相误操作。凡是EA皆不可缺少，非常非常重要！
/*
extern 确定从外部程序输入的变量，会直接显现输入数据窗口。数列本身不能作为外部变量。
注意：iMA中的MovingShift（均线偏移量）是指均线指标在图上绘制时向左、右移动的K线个数，主要为了使图中结果更好看，并不会对MA的计算数值产生变化。其中，该参数为正时，代表向右移动；为负值，则代表向左移动。
*/
extern double Lots = 0.1; //每单的交易量
extern double MaximumRisk = 0.02; //本系统最大风险系数，即可以动用总资金的2%
extern double DecreaseFactor = 3; //下跌因素个数
extern double MovingPeriod = 12; //均线的计算周期=12，为MA必须的参数之一；
extern double MovingShift = 6; //均线转移量=6，为MA必须的参数之一；
//+------------------------------------------------------------------+
// Calculate open positions |
// 自定义函数，仓单查询与统计 |
//+------------------------------------------------------------------+
int CalculateCurrentOrders(string symbol) //函数作用，计算当前持仓单的数量
{
int buys=0,sells=0; //定义两个局部变量，整数型，buys——多单数，sells——空单数，用于订单的统计
//----
for(int i=0;i<OrdersTotal();i++) //计次循环（i=0至订单数目，i=i+1）-循环检测当前的订单队列
{
if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false) break; //如果没有本系统交易的仓单类型，则跳出循环
if(OrderSymbol()==Symbol() && OrderMagicNumber()==MAGICMA)//是否仓单货币对是当前货币对且仓单编号是本系统编号,避免EA误操作其他程序控制的持仓单
{
if(OrderType()==OP_BUY) buys++; //如果仓单类型=多单，则：在多单数上加1；
if(OrderType()==OP_SELL) sells++; //如果仓单类型=空单，则，在空单数上加1。
}
}
//---- return orders volume
if(buys>0) return(buys); //如果多单>0，则返回多单数
else return(-sells); //如果仓单类型=空单，则返回负的空单数。
}
//+------------------------------------------------------------------+
//| Calculate optimal lot size
//| 自定义函数，管理资金并且计算开仓量
//+------------------------------------------------------------------+
double LotsOptimized()//开仓量计算函数（根据要求计算出订单交易量，返回一个浮点数）
{
double lot=Lots; //定义局部变量los为浮点数据类型
int orders=HistoryTotal(); // history orders total(已平仓单数)
int losses=0; // number of losses orders without a break(亏损单)
//---- select lot size
lot=NormalizeDouble(AccountFreeMargin()*MaximumRisk/1000.0,1); //开仓量=帐户可用资金*最大风险系数（=2%）/1000，并将结果保留小数点1位
//---- calcuulate number of losses orders without a break(计算亏损单数目)
if(DecreaseFactor>0) //如果下跌因素个数>0
{
for(int i=orders-1;i>=0;i--)
{
if(OrderSelect(i,SELECT_BY_POS,MODE_HISTORY)==false) { Print("Error in history!"); break; }
//如果没有本系统交易记录，输出“无交易历史！”,跳出循环
if(OrderSymbol()!=Symbol() || OrderType()>OP_SELL) continue;
//如果订单的货币对不是当前货币对，或者订单类型为挂单时，继续查找下一订单
//----
if(OrderProfit()>0) break; //如果盈利单数目>0，跳出循环
if(OrderProfit()<0) losses++; //如果盈利单数目<0，则在：亏损单数上加1
}
if(losses>1) lot=NormalizeDouble(lot-lot*losses/DecreaseFactor,1);
//如果亏损单数>1时，则重新计算下单量，并保留小数点后1位.
}
//---- return lot size
if(lot<0.1) lot=0.1; ///如果算出的交易量小于0.1手，则取交易量为0.1手
return(lot);
}
//+------------------------------------------------------------------+
//| Check for open order conditions 开仓策略 |
//+------------------------------------------------------------------+
void CheckForOpen() //开仓检查（判断开仓条件及其处理）
{
double ma;
int res;
//---- go trading only for first tiks of new bar
if(Volume[0]>1) return;
//---- get Moving Average –获取均线数值
ma=iMA(NULL,0,MovingPeriod,MovingShift,MODE_SMA,PRICE_CLOSE,0); //获取当前以收盘价为基准计算出的均线数值
//---- sell conditions -卖出条件
if(Open[1]>ma && Close[1]<ma) //如果前1根K线下穿均线（即K线的开盘价大于均线值、收盘价小于均线值）
{
res=OrderSend(Symbol(),OP_SELL,LotsOptimized(),Bid,3,0,0,"",MAGICMA,0,Red);
//开仓（当前货币对，卖出方向，开仓量计算（），买价，滑点=3，无止损，无止赢，订单编号，标上红色箭头），返回仓单号。
return;
}
//---- buy conditions
if(Open[1]<ma && Close[1]>ma) //如果前1根K线上穿均线（即K线的开盘价小于均线值、收盘价大于均线值）
{
res=OrderSend(Symbol(),OP_BUY,LotsOptimized(),Ask,3,0,0,"",MAGICMA,0,Blue);//开仓（当前货币对，买入方向，开仓量计算（），卖价，滑点=3，无止损，无止赢，订单编号，标上蓝色箭头），返回仓单号。
return;
}
//----
}
//+-------------------------------------------------------------------------+
//| Check for close order conditions -//自定义函数（无返回值）平仓策略 |
//+-------------------------------------------------------------------------+
void CheckForClose() //平仓检查（判断平仓条件及其处理）
{
double ma;
//---- go trading only for first tiks of new bar
//---- 只有在新K线的首次报价时执行（不是K线的开盘时间点，即当前k线还没收盘确定，则直接返回；否则，如果是K线第一个成交价，则向下继续运行）
if(Volume[0]>1) return;
//---- get Moving Average -获取均线数值
ma=iMA(NULL,0,MovingPeriod,MovingShift,MODE_SMA,PRICE_CLOSE,0); //获取当前以收盘价为基准计算出的均线数值
//----
for(int i=0;i<OrdersTotal();i++)
{
if(OrderSelect(i,SELECT_BY_POS,MODE_TRADES)==false) break; //如果没有本系统所交易的仓单时，跳出循环
if(OrderMagicNumber()!=MAGICMA || OrderSymbol()!=Symbol()) continue;
//如果仓单编号不是本系统编号，或者仓单货币对不是当前货币对时，继续选择
//---- check order type
if(OrderType()==OP_BUY) //如果是多单
{
if(Open[1]>ma && Close[1]<ma) OrderClose(OrderTicket(),OrderLots(),Bid,3,White); //如果第1根K线开盘价下穿均线时（即开盘价高于均价而收盘价低于均价时），
//则进行多头平仓（仓单编号，持仓数量，买价，滑点=3，用白色箭头显示）。
break; //跳出循环
}
if(OrderType()==OP_SELL)
{
if(Open[1]<ma && Close[1]>ma) OrderClose(OrderTicket(),OrderLots(),Ask,3,White);
//如果第1根K线开盘价上穿均线时（即开盘价低于均价而收盘价高于均价时），
//则进行空头平仓（仓单编号，持仓数量，卖价，滑点=3，用白色箭头显示）。
break; //跳出循环
}
}
//----
}
void deinit() {
Comment("www.eazhijia.com");//注释函数，可以不用。
}
//+------------------------------------------------------------------+
//| Start function //主程序—-每次成交价所驱动的运算过程 |
//+------------------------------------------------------------------+
void start()
{
//---- check for history and trading —对交易历史进行检查
if(Bars<100 || IsTradeAllowed()==false) return; //如果K线数少于100根，或者如果允许智能交易交易=假时，返回
//---- calculate open orders by current symbol -计算当前货币对的开仓订单
if(CalculateCurrentOrders(Symbol())==0) CheckForOpen(); //如果计算出当前货币对开仓订单数=0 （即没有仓单），则进行开仓检查。
else CheckForClose(); //否则（即当前已经有仓单时），则进行平仓检查。
//----
}
//+------------------------------------------------------------------+

复制代码

wending · 发表于 2017-4-7 10:22:15

EA代写，可回测EA复制，观摩账号策略破解，QQ3334851624

发表于 2017-4-7 10:43:41

先谢楼主分享

多米狼 · 发表于 2017-4-7 15:00:36

第一次接触

tom999 · 发表于 2017-4-9 18:17:36

谢谢分享……

引擎子 · 发表于 2017-10-26 01:02:30

谢谢分享……

zht8060 · 发表于 2018-2-28 13:56:15

市场都是对的？那是放屁！

ea编程 · 发表于 2018-5-6 09:32:47

Average_ch EA采用均线策略在交易。所以函数都用中文做了详细注释

飞鱼521 · 发表于 2019-3-11 04:30:21

我们努力把EA做的更完美

qiaojun · 发表于 2019-3-14 23:29:36

楼主分享我们努力把EA做的更完美